[@main]
#IF
LARGE G5 90
#SAY
　　<color=green 每个人都有属于自己的幸运，只有擅于把握机会的人才>\
<color=green 会获得幸运的奖励！>我是你的幸运大使，活动期间，勇士若\
在我这里打开<color=green 幸运礼包>，就可获得<丰厚奖励/@jieshao2>！<color=green 特别幸运的勇>\
<color=green 士还可获得2倍、4倍甚至高达8倍的经验奖励，最高可直接>\
<color=green 获得2亿经验巨奖！>勇士千万别错过自己的幸运！\
　　<购买幸运礼包/@goumai> <查看规则/@jieshao> <查看个人次数/@zijizhufu>\
　　<查看今日排名/@paihangcur&0&1&13&5&6> <查看昨日排名/@paihangyes&0&1&13&5&6>\
　　<打开幸运礼包/@Lucky> <领取昨日奖励/@getPrizeD> <“幸运”兑奖/@duihuan>\
#ELSESAY
　　\　　现在是广告时间请等开区90分钟以后在来把!\\
　　游戏已运行了【<$STR(G5)>】分!\
　　<离开/@exit>\

[@duihuan]
　　<color=orange 集齐“幸运”2字>就可兑换<color=green “数亿经验、权威级天人技>\
<color=green 能书、专家骑战技能书、圣王首饰”等丰厚奖励！>特别幸运\
者还可直接兑换得到<color=red “幸运靴子”>的超级大奖！\
　　如果你包裹中有“幸”、“运”的话请尽快给我吧！\
　　<color=orange 注：兑换结束时间请注意游戏内公告！>\\
　　<“幸”“运”兑换奖励/@lingqu>\
　　<离开/@exit>\

[@lingqu]
#IF
!checkitem 幸 1
!checkitem 运 1
#SAY
　　你包裹里没有“幸”“运”字，不能兑换奖励！\\
　　<离开/@exit>\
#ACT
break
#ELSEACT
#IF
RANDOM 1500
#ACT
TAKE 幸 1
TAKE 运 1
give 幸运靴子1
SENDMSG 10 恭喜<$USERNAME>在幸运大使兑换“幸”“运”，获得幸运靴子奖励。
close
break
#IF
RANDOM 3
#ACT
TAKE 幸 1
TAKE 运 1
ReadRandomStr ..\QuestDiary\数据文件\游戏奖励\幸运礼包奖励.txt S0
give $STR(S0) 1
SENDMSG 10 恭喜<$USERNAME>在幸运大使兑换“幸”“运”，获得<$STR(S0)>奖励。
close
break
#IF
RANDOM 1
#ACT
TAKE 幸 1
TAKE 运 1
CHANGEEXP + 100000000
SENDMSG 10 恭喜<$USERNAME>在幸运大使兑换“幸”“运”，获得1亿经验奖励。
close
break

[@getPrizeD]
#IF
CHECKLEVELEX > 0
#ACT
MOV S1 |
INC S1 $USERNAME
INC S1 |
#IF
!PosEx $STR(S1) .\QuestDiary\数据文件\临时数据\日期活动\礼包次数奖励.txt S2
#SAY
　　你昨天开启幸运礼包次数不足15次，没有经验奖励！\\
　　<离开/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKLEVELEX > 0
#ACT
GETVALIDSTR $STR(S2) | S3 S4
GETVALIDSTR $STR(S4) | P0 S3
#IF
SMALL P0 15
#SAY
　　你昨天开启幸运礼包次数不足15次，没有经验奖励！\\
　　<离开/@exit>\
#ACT
break
#ELSEACT
#IF
LARGE P0 149
#ACT
CHANGEEXP + 100000000
DELVARLIST $STR(S2) ..\QuestDiary\数据文件\临时数据\日期活动\礼包次数奖励.txt
SENDMSG 5 恭喜你领取了1亿经验。
SENDMSG 10 恭喜<$USERNAME>在幸运大使领取了昨日奖励，获得1亿经验。
close
break
#ELSEACT
DIV P0 15
MUL P0 10000000
CHANGEEXP + $STR(P0)
DELVARLIST $STR(S2) ..\QuestDiary\数据文件\临时数据\日期活动\礼包次数奖励.txt
SENDMSG 5 恭喜你领取了<$STR(P0)>经验。
SENDMSG 10 恭喜<$USERNAME>在幸运大使领取了昨日奖励，获得<$STR(P0)>经验。
close
break

[@zijizhufu]
#IF
CHECKLEVELEX > 0
#ACT
MOV S1 |
INC S1 $USERNAME
INC S1 |
#IF
PosEx $STR(S1) .\QuestDiary\数据文件\排名信息\礼包今日排名.txt S2
#ACT
GETVALIDSTR $STR(S2) | S3 S4
GETVALIDSTR $STR(S4) | S2 S3
MOV P2 $STR(S2)
#ELSEACT
MOV P2 0
#IF
PosEx $STR(S1) .\QuestDiary\数据文件\排名信息\礼包昨日排名.txt S12
#ACT
GETVALIDSTR $STR(S12) | S13 S14
GETVALIDSTR $STR(S14) | S12 S13
MOV P12 $STR(S12)
#ELSEACT
MOV P12 0
#IF
CHECKLEVELEX > 0
#SAY
　　你今天开启次数：{Color=Green <$STR(P2)>}次。\
　　你昨天开启次数：{Color=Green <$STR(P12)>}次。\\
　　<返回/@main>\

[@paihangcur]
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt S0 $PARAM(50)
MOV P0 $PARAM(50)
MOV P1 $PARAM(51)
#IF
EQUAL S0 无
#SAY
　　目前暂无信息，请稍后查看。\\
　　<离开/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt S0 $STR(P0)
#IF
!EQUAL S0 无
#ACT
MOV S1 第[]
INC S1 $str(P1)
INC S1 名
FORMATSTR S3 %-10s%-18s%-12s{Color=orange#32%s} <$STR(S1)>|<$STR(S0)>
MOV S4 $STR(S3)
INC S4 \
INC P0 1
INC P1 1
GOTO @今日排行排序

[@今日排行排序]
#IF
LARGE $TXT(.\QuestDiary\数据文件\排名信息\礼包今日排名.txt) $PARAM(53)
EQUAL P0 $PARAM(52)
#SAY
　　 <Color=Green 昨日排名>\
<Color=Green 名次 角色名 开启次数 当前奖励>\
<$STR(S4)>
　　<第 1页/@paihangcur&0&1&13&5&6> <第 2页/@paihangcur&5&6&13&5&6>\
<返回/@main> <关闭/@exit>\
#ACT
break
#ELSEACT
#IF
SMALL $TXT(.\QuestDiary\数据文件\排名信息\礼包今日排名.txt) $PARAM(54)
EQUAL P0 $PARAM(52)
#SAY
　　 <Color=Green 昨日排名>\
<Color=Green 名次 角色名 开启次数 当前奖励>\
<$STR(S4)>
　　<第 1页/@paihangcur&0&1&13&5&6>\
<返回/@main> <关闭/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt S0 $str(P0)
#IF
CHECKLEVELEX > 0
#ACT
#ELSEACT
BREAK
#IF
EQUAL S0 无
#ACT
MOV P0 $PARAM(52)
GOTO @今日排行排序
BREAK
#ELSEACT
#IF
equal P1 6
#ACT
MOV P0 $PARAM(52)
GOTO @今日排行排序
break
#IF
equal P1 11
#ACT
MOV P0 $PARAM(52)
GOTO @今日排行排序
break
#IF
SMALL P1 10
#ACT
MOV S1 第[]
INC S1 $str(P1)
INC S1 名
#ELSEACT
MOV S1 第10名
#IF
CHECKLEVELEX > 0
#ACT
FORMATSTR S3 %-10s%-18s%-12s{Color=orange#32%s} <$STR(S1)>|<$STR(S0)>
INC S4 $STR(S3)
INC S4 \
INC P0 1
INC P1 1
GOTO @今日排行排序
break

[@paihangyes]
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包昨日排名.txt S0 $PARAM(50)
MOV P0 $PARAM(50)
MOV P1 $PARAM(51)
#IF
EQUAL S0 无
#SAY
　　目前暂无信息，请稍后查看。\\
　　<离开/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包昨日排名.txt S0 $STR(P0)
#IF
!EQUAL S0 无
#ACT
MOV S1 第[]
INC S1 $str(P1)
INC S1 名
FORMATSTR S3 %-10s%-18s%-12s{Color=orange#32%s} <$STR(S1)>|<$STR(S0)>
MOV S4 $STR(S3)
INC S4 \
INC P0 1
INC P1 1
GOTO @昨日排行排序

[@昨日排行排序]
#IF
LARGE $TXT(.\QuestDiary\数据文件\排名信息\礼包昨日排名.txt) $PARAM(53)
EQUAL P0 $PARAM(52)
#SAY
　　 <Color=Green 昨日排名>\
<Color=Green 名次 角色名 开启次数 当前奖励>\
<$STR(S4)>
　　<第 1页/@paihangyes&0&1&13&5&6> <第 2页/@paihangyes&5&6&13&5&6>\
<返回/@main> <关闭/@exit>\
#ACT
break
#ELSEACT
#IF
SMALL $TXT(.\QuestDiary\数据文件\排名信息\礼包昨日排名.txt) $PARAM(54)
EQUAL P0 $PARAM(52)
#SAY
　　 <Color=Green 昨日排名>\
<Color=Green 名次 角色名 开启次数 当前奖励>\
<$STR(S4)>
　　<第 1页/@paihangyes&0&1&13&5&6>\
<返回/@main> <关闭/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包昨日排名.txt S0 $str(P0)
#IF
CHECKLEVELEX > 0
#ACT
#ELSEACT
BREAK
#IF
EQUAL S0 无
#ACT
MOV P0 $PARAM(52)
GOTO @昨日排行排序
BREAK
#ELSEACT
#IF
equal P1 6
#ACT
MOV P0 $PARAM(52)
GOTO @昨日排行排序
break
#IF
equal P1 11
#ACT
MOV P0 $PARAM(52)
GOTO @昨日排行排序
break
#IF
SMALL P1 10
#ACT
MOV S1 第[]
INC S1 $str(P1)
INC S1 名
#ELSEACT
MOV S1 第10名
#IF
CHECKLEVELEX > 0
#ACT
FORMATSTR S3 %-10s%-18s%-12s{Color=orange#32%s} <$STR(S1)>|<$STR(S0)>
INC S4 $STR(S3)
INC S4 \
INC P0 1
INC P1 1
GOTO @昨日排行排序
break

[@Lucky]
#ACT
checkitembox 请放入幸运礼包： 1 3
#SAY
　　勇士开启<color=green 幸运礼包>时，必可至少<color=orange 获得2000万经验的基础>\
<color=orange 奖励>，特别幸运的勇士还可直接获得<color=orange 2倍经验(5000万)、4倍>\
<color=orange 经验(1亿)甚至8倍经验(2亿)的超级大奖！>\
　　<color=green 此外，勇士每次开启幸运礼包时，除获得经验外，每次>\
<color=green 都有机会获得“幸”、“运”两字的奖励！>积齐“幸运”2\
字就可兑换<color=orange 包括幸运靴子在内的各种丰厚好礼！>\

[@getboxitem3]
#IF
LARGE G0 0
#SAY
　　内测期间此功能关闭。\\
　　<离开/@Exit>\
#ACT
break
#IF
CHECKBAGSIZE 1
#ACT
#ELSEACT
MessageBox 对不起，您身上背包的位置不够，请清理出空位。
break
#IF
checkitemx 幸运礼包
#ACT
takeid $CHECKBOXITEM.ItemExD
GOTO @给予奖励
break
#IF
checkitemx 幸运礼包(捆)
#ACT
MOV S3 $CHECKBOXITEM.ItemExD
MOV P1 $ItemEx.$STR(S3).13
GOTO @检测幸运礼包
break
#ELSESAY
　　你似乎给错东西了？你可以在我这里购买幸运礼包。\\
　　<离开/@exit>

[@检测幸运礼包]
#IF
SMALL P1 1
#SAY
　　你似乎给错东西了？你可以在我这里购买幸运礼包。\\
　　<离开/@exit>
#ACT
takeid $STR(S3)
break
#IF
SMALL P1 2
#ACT
takeid $STR(S3)
GOTO @给予奖励
break
#ELSEACT
UpgradeUserItemEx $STR(S3) 13 - 1
GOTO @给予奖励
break

[@给予奖励]
#IF
RANDOM 80
#ACT
MOV D60 0
CHANGEEXP + 20000000
give 运 1
UpgradeUserItemEx $PARAM(0) 71 = 1
SENDMSG 5 恭喜你打开了幸运礼包获得了2000万经验。并获得了 “运”字。
SENDMSG 10 恭喜<$USERNAME>在幸运大使打开幸运礼包获得了2000万经验。并获得了 “运”字。
GOTO @幸运排名
checkitembox 请放入幸运礼包： 1 3
break
#IF
RANDOM 70
#ACT
MOV D60 0
CHANGEEXP + 20000000
give 幸 1
UpgradeUserItemEx $PARAM(0) 71 = 1
SENDMSG 5 恭喜你打开了幸运礼包获得了2000万经验。并获得了 “幸”字。
SENDMSG 10 恭喜<$USERNAME>在幸运大使打开幸运礼包获得了2000万经验。并获得了 “幸”字。
GOTO @幸运排名
checkitembox 请放入幸运礼包： 1 3
break
#IF
RANDOM 1
#ACT
MOV D60 0
CHANGEEXP + 20000000
SENDMSG 5 恭喜你打开了幸运礼包获得了2000万经验。
SENDMSG 10 恭喜<$USERNAME>在幸运大使打开幸运礼包获得了2000万经验。
GOTO @幸运排名
checkitembox 请放入幸运礼包： 1 3
break

[@幸运排名]
#IF
CHECKLEVELEX > 0
#ACT
MOV D60 1
MOV S1 |
INC S1 $USERNAME
INC S1 |
#IF
PosEx $STR(S1) .\QuestDiary\数据文件\排名信息\礼包今日排名.txt S2
#ACT
GETVALIDSTR $STR(S2) | S3 S4
GETVALIDSTR $STR(S4) | S3 S4
MOV P2 $STR(S3)
INC D60 $STR(P2)
MOV P5 0
#ELSEACT
MOV D60 1
MOV P5 0
#IF
CHECKLEVELEX > 0
#ACT
#ELSEACT
BREAK
#IF
CHECKLEVELEX > 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt S5 9
#IF
equal S5 无
#ACT
goto @礼包排行系统
break
#ELSEACT
GETVALIDSTR $STR(S5) | S5 S6
GETVALIDSTR $STR(S6) | P4 S5
#IF
large D60 $STR(P4)
#ACT
goto @礼包排行系统
break
#ELSEACT
DELVARLIST $STR(S2) ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt
MOV S7 |
INC S7 $USERNAME
INC S7 |
INC S7 $STR(D60)
INC S7 |　
ADDVARLIST $STR(S7) ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt
BREAK

[@礼包排行系统]
#IF
LARGE P5 10
#ACT
break
#ELSEACT
#IF
CHECKLEVELEX > 0
#ACT
MOV S1 |
INC S1 $USERNAME
INC S1 |
#IF
PosEx $STR(S1) .\QuestDiary\数据文件\排名信息\礼包今日排名.txt S7
#ACT
DELVARLIST $STR(S7) ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt S8 $STR(P5)
#ELSEACT
ReadRandomStr ..\QuestDiary\数据文件\排名信息\礼包今日排名.txt S8 $STR(P5)
#IF
CHECKLEVELEX > 0
#ACT
#ELSEACT
BREAK
#IF
!equal S8 无
#ACT
GETVALIDSTR $STR(S8) | S8 S9
GETVALIDSTR $STR(S9) | P6 S9
#ELSEACT
MOV P6 0
#IF
large D60 $STR(P6)
#ACT
MOV S7 |
INC S7 $USERNAME
INC S7 |
INC S7 $STR(D60)
INC S7 |　
INSERTVARLIST $STR(P5) $STR(S7) .\QuestDiary\数据文件\排名信息\礼包今日排名.txt
break
#ELSEACT
inc P5 1
goto @礼包排行系统
break

[@goumai]
　　<color=green 开启幸运礼包，开启你的幸运！>活动期间，打开幸运礼\
包皆可获得<丰厚奖励/@jieshao2>！<color=green 特别幸运的勇士还可获得2倍、4倍甚>\
<color=green 至高达8倍的经验奖励，最高可直接获得2亿经验巨奖！>\
　　我随时可能离开，勇士请把握机会！\\
　　<购买1个幸运礼包（20 元宝）/@buy5>\
　　<购买1捆幸运礼包（400元宝）/@buy100>\

[@buy100]
#IF
CHECKGAMEGOLD < 400
#SAY
　　你好像没有这么多元宝啊！\\
　　<我再看看/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKBAGSIZE 1
#ACT
GAMEGOLD - 400
GIVE 幸运礼包(捆) 1
SENDMSG 5 恭喜你购买成功。
close
break
#ELSEACT
SENDMSG 5 对不起，您身上背包的位置不够，请清理出空位！
close
break

[@buy5]
#IF
CHECKGAMEGOLD < 20
#SAY
　　你好像没有这么多元宝啊！\\
　　<我再看看/@exit>\
#ACT
break
#ELSEACT
#IF
CHECKBAGSIZE 1
#ACT
GAMEGOLD - 20
GIVE 幸运礼包 1
SENDMSG 5 恭喜你购买成功。
close
break
#ELSEACT
SENDMSG 5 对不起，您身上背包的位置不够，请清理出空位！
close
break

[@jieshao]
　　新开传世私服勇士开启<color=green 幸运礼包>时，必可至少<color=orange 获得2000万经验的基础>\
<color=orange 奖励>，特别幸运的勇士还可直接获得<color=orange 2倍经验(5000万)、4倍>\
<color=orange 经验(1亿)甚至8倍经验(2亿)的超级大奖！>\
　　<color=green 此外，勇士每次开启幸运礼包时，除获得经验外，每次>\
<color=green 都有机会获得“幸”、“运”两字的奖励！>\
　　<color=green 积齐“幸运”2字>就可兑换<color=orange “数亿经验、权威级天人技>\
<color=orange 能书、专家骑战技能书、圣王首饰”>等丰厚奖励！特别幸运\
者还可直接兑换得到<color=red “幸运靴子”>的超级大奖！\
　　<离开/@exit> <返回/@main>\

[@jieshao2]
　　<color=orange 每日成就奖>：勇士们<color=green 当天每开启15次幸运礼包，就能获>\
<color=green 得1千万经验奖励，开启次数越多，累积经验奖励越多。>\
（注：每天奖励经验上限为1亿，请于次日24点前领取）\
　　<color=green 此外，勇士每次开启幸运礼包时，除获得经验外，每次>\
<color=green 都有机会获得“幸”、“运”两字的奖励！>\
　　<color=green 积齐“幸运”2字>就可兑换<color=orange “数亿经验、权威级天人技>\
<color=orange 能书、专家骑战技能书、圣王首饰”>等丰厚奖励！特别幸运\
者还可直接兑换得到<color=red “幸运靴子”>的超级大奖！\
　　<返回/@main>\